先輩〜、IF関数ってよく聞くんですけど、正直あんまりよくわかってなくて…使えると何が便利なんですか？
IF関数は“もし〜なら”って判断ができる関数なんだよ。SUMIFとかCOUNTIF、IFSも一緒に覚えると、めちゃ便利になるよ〜！
今日はまとめて教えちゃおう！
Excelの中でも、仕事で超よく使うのが「IF関数」。
「条件によって違う結果を出したい！」ってときの強い味方ですよね。
でも、IF関数だけじゃなくて、似たような条件付きの関数ってたくさんあるんです。
例えば、SUMIFやCOUNTIF、そして最近よく使われるIFS関数もそのひとつ。
これらをまとめて使いこなせると、データ集計や分析がグッとラクになるし、仕事の効率もグンとアップ！
この記事では、初心者でもわかりやすく、それぞれの関数の使い方をまるっと解説します。
条件付きで合計したり、カウントしたり、複数条件を扱える関数も一緒に使えば、エクセル作業の幅がぐ〜んと広がります！
IF関数の基本のキ
Excelで「条件に応じて表示を変えたいな〜」ってとき、一番よく使われるのがこの IF関数。
たとえば、「点数が80点以上なら“合格”、それ以外は“不合格”にしたい」って場面。
こんな感じの式で解決できます
=IF(B2>=80,"合格","不合格")
※B列が「点数」、C列に「IF関数」を使って判定しています。
IF関数の構造はこうなってる！
=IF(条件, 条件が真ならコレ, 偽ならコレ)「もし〇〇だったらこれ、じゃなかったらあれ」という風に、分岐をつくるのがIF関数の役割です。
数値だけじゃなくて「文字」や「空白」も判定できる！
▽入力されてない場合に「未入力」と表示
=IF(A2="","未入力","入力済み")
- A列が空白の場合 → B列に「未入力」
- それ以外（なにか入力されている）なら → 「入力済み」
▽「営業部」かどうかで判断
=IF(B2="営業部","OK","他部署")
- B列が「営業部」なら → C列に「OK」
- それ以外（総務部、開発部など）なら → 「他部署」
SUMIF／COUNTIFで、条件付き集計！
「営業部の売上だけ合計したい」
「80点以上の人が何人いるか数えたい」
そんな“条件付き”の集計には、SUMIF関数とCOUNTIF関数が大活躍します！
SUMIF：条件に合うものだけ合計！
書き方の基本
=SUMIF(範囲, 条件, 合計範囲)「営業部の売上だけ合計したい！」という場合は
=SUMIF(B2:B6,"営業部",C2:C6)
この場合、営業部の売上合計は：
500,000 + 450,000 + 550,000 = 1,500,000円
COUNTIF：条件に合うものを数える！
書き方の基本
=COUNTIF(範囲, 条件)「80点以上の人は何人？」という場合は
=COUNTIF(B2:B6,">=80")
田中さん・佐藤さん・山本さん → 合計3人！
「特定の文字列を含む」もOK！
ワイルドカード「*」が使えます！
=SUMIF(A2:A10,"*田*",B2:B10)=COUNTIF(A2:A10,"*田*")
- 名前に「田」が含まれる人の売上を合計！
- 名前に「田」が含まれる人をカウント！
IFS関数でネスト地獄から脱出！
Excelで「点数によって評価を変えたい！」
そんなとき、昔からの方法だと IF を何重にもネスト（入れ子）しがち。
でも安心してください。
そんな“ネスト地獄”から救ってくれる救世主がIFS関数です！
書き方の基本
=IFS( 条件1, 結果1, 条件2, 結果2, 条件3, 結果3, … ,TRUE, すべての条件を満たさないとき)- 複数条件に対応（最大127ペアまでOK！）
- 順番に上から評価される（最初にマッチした条件で確定）
- TRUE関数と組み合わせて「すべて外れたときの処理」もできる
たとえば、点数に応じて評価をしたいとき：
- 90点以上 → 「S」
- 80点以上 → 「A」
- 70点以上 → 「B」
- 60点以上 → 「C」
- それ未満 → 「D」
これをIFで書くと…
=IF(A2>=90,"S",IF(A2>=80,"A",IF(A2>=70,"B",IF(A2>=60,"C","D"))))カッコが多くて見づらいし、ミスしやすい…。
IFS関数ならスッキリします！
=IFS(A2>=90,"S", A2>=80,"A", A2>=70,"B", A2>=60,"C", A2<60,"D")
条件と結果をペアで、順番に書いていくだけ。
カッコの深さで迷うことがありません
TRUE関数と組み合わせて「すべて外れたときの処理」をするときは、
例：どの条件にも当てはまらなかったら「未評価」
=IFS(B2>=90,"S", B2>=80,"A", B2>=70,"B", B2>=60,"C", B2>40,"D", TRUE,"未評価")
40点以下または点数未入力の場合に「未評価」と表示します。
IF関数＋他の関数の組み合わせ技
IF関数は、条件に応じて表示を切り替えるだけではありません。
他の関数と組み合わせると、もっと賢く、便利に使えます。
例①：合格者が多いかどうかを判定！
IF関数とCOUNTIF関数を組み合わせます。
=IF(COUNTIF(B2:B10,"合格")>5,"多数合格","少数合格")
「合格」が６人いるので「多数合格」になります！
例②：合計売上が500以上なら「目標達成」
IF関数とSUMIF関数を組み合わせます。
=IF(SUMIF(A1:A7,">=80",B1:B7)>500,"目標達成","要改善")
点数80点以上の売上合計が410なので「要改善」になります。
IF関数 × AND／OR
複数条件が絡む場合は、AND や OR を IF に組み込むのが便利！
例①：点数80以上かつ合格なら「優秀」
=IF(AND(A2>=80,B2="合格"),"優秀","再評価")
- A列：点数
- B列：合否
- 両方の条件を満たすと「優秀」になります！
例②：営業部または販売部なら「接客職」
=IF(OR(B2="営業部",B2="販売部"),"接客職","その他")
- 「営業部」「販売部」のどちらかなら「接客職」と表示
- それ以外は「その他」
AND・ORの違いをざっくり整理すると次の表のとおりです。
| 関数 | 条件の意味 | 例 |
|---|---|---|
| AND | すべての条件を満たす | A2>=80 かつ B2=”合格” |
| OR | どれか1つでもOK | B2=”営業部” または B2=”販売部 |
IF＋TEXT関数
IF関数とTEXT関数を組み合わせることで、条件に応じてフォーマットを調整した結果を表示することができます。
=IF(A2>=80,TEXT(A2,"0点 (優秀)"),TEXT(A2,"0点 (再評価)"))
A列の値が80以上の場合は「〇点 (優秀)」、80未満の場合は「〇点 (再評価)」というフォーマットで表示されます。
=IF(A2>=0,"利益："&TEXT(A2,"#,##0")&"円","損失："&TEXT(-A2,"#,##0")&"円")
A列の値が0以上なら「利益：〇〇円」、0未満なら「損失：〇〇円」と表示されます。カンマ区切りのフォーマットにより、金額の視認性も向上しています。
まとめ
今回は、Excelの基本中の基本「IF関数」から、条件付き集計で大活躍の「SUMIF」「COUNTIF」、そしてネストの悩みを解消する「IFS関数」まで、便利な使い方をまるっと紹介しました。
ポイントは、
- IF関数は条件分岐の王様！「もし〜なら」の判定が超カンタンにできる
- SUMIF・COUNTIFで条件付き集計がラクラク！
- IFS関数を使えば、複雑なネストIFからスッキリ解放！
- ANDやOR関数と組み合わせると、もっと複雑な条件も自由自在
これらを知って使いこなせれば、日々のデータ処理や分析がグッと早く、ラクになります。
ぜひ、この記事で学んだテクニックを試してみてくださいね！
よーし、IF も SUMIF も COUNTIF も IFS も…ぜんぶバンバン使ってやる〜っ！
Excel、もう怖くないぞっ♪
